home *** CD-ROM | disk | FTP | other *** search
/ Apple II Magazines (PO) / Bits and Bytes Volume 10, No. 03 (1988-10)(Apple Computing Enjoyment Society)(Side B).zip / Bits and Bytes Volume 10, No. 03 (1988-10)(Apple Computing Enjoyment Society)(Side B).po / WHEEL.OF.FORTUN.bas < prev   
BASIC Source File  |  1996-12-24  |  17KB  |  176 lines
  1. 1  REM <CTRL-H><CTRL-H><CTRL-H><CTRL-H><CTRL-H><CTRL-H><CTRL-H>----------------<CTRL-M><CTRL-M>WHEEL OF FORTUNE<CTRL-M><CTRL-M>JOE ISHAM<CTRL-M><CTRL-M>----------------
  2. 2  FOR L = 1 TO 40: POKE 33,L: PRINT : FOR PAUSE = 1 TO 40: NEXT : NEXT : FOR L = 1 TO 24: PRINT : FOR PAUSE = 1 TO 40: NEXT : NEXT : VTAB 1: FOR L = 1 TO 20: PRINT "][";: NEXT L: FOR L = 2 TO 23: VTAB L: HTAB 1: PRINT "][";: HTAB 39: PRINT "][";: NEXT L: FOR K = 19 TO 23  STEP 4: VTAB K: FOR L = 1 TO 20: PRINT "][";: NEXT L,K
  3. 3  DEF  FN IP(C) = IP(2) +IP(3) +IP(4) +IP(6) +IP(7) +IP(8) +IP(10) +IP(11) +IP(12) +IP(13) +IP(14) +IP(16) +IP(17) +IP(18) +IP(19) +IP(20) +IP(22) +IP(23) +IP(24) +IP(25) +IP(26)
  4. 4 QA = 101
  5. 5  DIM WH$(30),WI$(30),WJ$(30),RE$(QA),IT$(QA),IP(26),UP(QA)
  6. 6  FOR LOOP = 1 TO QA: READ REAL$(LOOP),ITZA$(LOOP): NEXT LOOP: DATA THE PRINCE AND PRINCESS OF WALES,PEOPLE,THE GOLDEN GATE BRIDGE,A LANDMARK,RONALD WILSON REAGAN,A PERSON,THE TAJ MAHAL,A LANDMARK,SALT LAKE CITY,A PLACE
  7. 7  DATA WATER TOWER,A THING,THE FLORIDA KEYS,A PLACE,DWIGHT DAVID EISENHOWER,A PERSON,PEANUTS,THINGS,NORTHAMPTONSHIRE,A PLACE,SALT AND PEPPER SHAKERS,THINGS,THE OLYMPIC GAMES,AN EVENT,AIR CONDITIONER,A THING
  8. 8  DATA  JOHN WESLEY HARDIN,A PERSON,SAM HOUSTON,A PERSON,CHRISTOPHER COLUMBUS,A PERSON,QUEEN ELIZABETH AND PRINCE PHILIP,PEOPLE,MARGARET THATCHER,A PERSON,SAM RAYBURN,A PERSON,JIMMY DURANTE,A PERSON,CONRAD HILTON,A PERSON
  9. 9  DATA REUNION ARENA,A PLACE,MANHATTAN ISLAND,A PLACE,THE EIFFEL TOWER,A LANDMARK,GINA LOLLOBRIGIDA,A PERSON,HENRY WADSWORTH LONGFELLOW,A PERSON,BENJAMIN FRANKLIN PIERCE,A FICTIONAL CHARACTER
  10. 10  DATA GREENLAND,A PLACE,ORBIT THE EARTH,A PHRASE,ROYAL CANADIAN MOUNTED POLICE,PEOPLE,DUTCH DOOR,A THING,SANTA FE NEW MEXICO,A PLACE,ROBERT FROST,A PERSON,PUT TWO AND TWO TOGETHER,A PHRASE,ABSENCE OF MALICE,A TITLE
  11. 11  DATA HIGH TIDE,A THING,MOTHER GOOSE,A FICTIONAL CHARACTER,MEASURE FOR MEASURE,A TITLE,WALKING A THIN LINE,A PHRASE,YUKON TERRITORY,A PLACE,DIANA ROSS,A PERSON,LET BYGONES BE BYGONES,A PHRASE,MAINE LOBSTER,A THING
  12. 12  DATA IS THERE A DOCTOR IN THE HOUSE,A PHRASE,SODOM AND GOMORRAH,PLACES,DRAFT BEER,A THING,UNIDENTIFIED FLYING OBJECT,A THING,DICK CAVETT,A PERSON,PRAISE THE LORD AND PASS THE AMMUNITION,A TITLE,TURN OVER A NEW LEAF,A PHRASE
  13. 13  DATA MILK CHOCOLATE,A THING,ON GOLDEN POND,A TITLE,SKINNY AS A RAIL,A PHRASE,CONGRESSIONAL RECORD,A TITLE,WHEAT GERM,A THING,FALSE ALARM,A THING,UNFINISHED BUSINESS,A PHRASE,BORN WITH A SILVER SPOON IN YOUR MOUTH,A PHRASE
  14. 14  DATA MAUREEN STAPLETON,A PERSON,PARK AVENUE,A PLACE,CATSKILL MOUNTAINS,A PLACE,MERYL STREEP,A PERSON,THE STRAW THAT BROKE THE CAMEL'S BACK,A PHRASE,BIRD OF PARADISE,A THING,INSTANT COFFEE,A THING
  15. 15  DATA PUMPERNICKEL BREAD,A THING,HALF A LOAF IS BETTER THAN NONE,A PHRASE,BACK TO THE SALT MINES,A PHRASE,BURLESQUE SHOW,A THING,I'M ALWAYS CHASING RAINBOWS,A PHRASE,STRAIGHT AS AN ARROW,A PHRASE
  16. 16  DATA JASON ROBARDS,A PERSON,OLD FAITHFUL,A LANDMARK,CHERRY BLOSSOM FESTIVAL,AN EVENT,LIVING HIGH ON THE HOG,A PHRASE,FIGHT FIRE WITH FIRE,A PHRASE,ATLANTA BRAVES,PEOPLE,CAULIFLOWER,A THING,POCKET WATCH,A THING
  17. 17  DATA DON'T DRINK THE WATER,A TITLE,PILOT LIGHT,A THING,TWENTY THOUSAND LEAGUES UNDER THE SEA,A TITLE,SPENCER TRACY,A PERSON,PUEBLO COLORADO,A PLACE,DOUBLE CHIN,A THING,PIGS IN A BLANKET,THINGS,QUOTATION MARKS,THINGS
  18. 18  DATA  FREIGHT TRAIN,A THING,DAMSEL IN DISTRESS,A PERSON,STANDING ROOM ONLY,A PHRASE,COOPERSTOWN NEW YORK,A PLACE,ASTRONAUT,AN OCCUPATION,THE STARS AND STRIPES FOREVER,A TITLE,IF AT FIRST YOU DON'T SUCCEED TRY AGAIN,A PHRASE
  19. 19  DATA JANE WYMAN,A PERSON,ORDER IN THE COURT,A PHRASE,SAN FRANCISCO BAY,A PLACE,REMBRANDT,A PERSON,IN ONE EAR AND OUT THE OTHER,A PHRASE,GREAT SMOKY MOUNTAINS,A PLACE,CAPITOL HILL,A PLACE
  20. 30  VTAB 7: HTAB 13: PRINT "WHEEL OF FORTUNE": VTAB 9: HTAB 4: PRINT "BASED ON THE NBC TELEVISION SERIES": VTAB 10: HTAB 11: PRINT "HOSTED BY PAT SAJAK": VTAB 13: HTAB 7: PRINT "PROGRAM WRITTEN BY JOE ISHAM"
  21. 40  REM SET UP WHISTLE
  22. 41  POKE 771,162: POKE 772,1: POKE 773,142: POKE 774,2: POKE 775,3: POKE 776,169: POKE 777,4: POKE 778,141: POKE 779,1
  23. 42  POKE 780,3: POKE 781,142: POKE 782,0: POKE 783,3: POKE 784,32: POKE 785,31: POKE 786,3: POKE 787,174: POKE 788,2
  24. 43  POKE 789,3: POKE 790,232: POKE 791,224: POKE 792,120: POKE 793,142: POKE 794,2: POKE 795,3: POKE 796,144: POKE 797,234
  25. 44  POKE 798,96: POKE 799,173: POKE 800,48: POKE 801,192: POKE 802,136: POKE 803,208: POKE 804,5: POKE 805,206: POKE 806,1
  26. 45  POKE 807,3: POKE 808,240: POKE 809,9: POKE 810,202: POKE 811,208: POKE 812,245: POKE 813,174: POKE 814,0: POKE 815,3
  27. 46  POKE 816,76: POKE 817,31: POKE 818,3: POKE 819,96
  28. 47 FL$ = "TNSRHLDCFPMWYBGVKQXJZ"
  29. 48  READ MV(1): FOR LOOP = 1 TO 24: READ WH$(LOOP): NEXT LOOP: DATA 750,BANKRUPT,350,250,600,400,150,200,250,400,LOSE A TURN,450,150,200,100,FREE SPIN,200,300,400,500,100,200,300,175,750
  30. 49  READ MV(2): FOR LOOP = 1 TO 24: READ WI$(LOOP): NEXT LOOP: DATA 1000,BANKRUPT,600,250,200,1000,150,300,400,750,450,LOSE A TURN,800,150,900,250,BANKRUPT,400,550,300,200,900,200,400,300
  31. 50  READ MV(3): FOR LOOP = 1 TO 24: READ WJ$(LOOP): NEXT LOOP: DATA 2000,BANKRUPT,700,500,350,400,550,300,200,900,200,400,300,BANKRUPT,600,250,200,LOSE A TURN,350,2000,500,250,300,800,1500
  32. 51  VTAB 21: HTAB 11: PRINT "INSTRUCTIONS (";: INVERSE : PRINT "Y";: NORMAL : PRINT "/N) ?";: GET YN$: PRINT 
  33. 52  IF YN$ = "N"  THEN  VTAB 20: CALL  -958: VTAB 22: GOTO 96
  34. 53  HOME : INVERSE : PRINT "WHEEL OF FORTUNE": NORMAL : PRINT : PRINT "THIS GAME IS BASED ON THE NBC-TV GAME   SHOW 'WHEEL OF FORTUNE.'  IN THIS GAME, YOUR OBJECT IS TO SOLVE PUZZLES LIKE YOUWOULD SOLVE WHEN PLAYING 'HANGMAN.'  YOUEARN MONEY EACH TIME YOU GUESS";
  35. 54  PRINT " COR-     RECTLY, BUT IF YOU HIT ";: INVERSE : PRINT "BANKRUPT";: NORMAL : PRINT ", YOU    LOSE IT ALL!": PRINT : PRINT "VOWELS COST $250 EACH, BUT CONSONANTS   ARE FREE."
  36. 55  PRINT : PRINT "IF YOU WANT THE COMPUTER TO PLAY ONE OR MORE OF THE THREE PLAYERS, SIMPLY TYPE  ";: INVERSE : PRINT "APPLE";: NORMAL : PRINT " AS THE PLAYER'S NAME(S)."
  37. 56  PRINT : FLASH : PRINT "NOTE";: NORMAL : PRINT ": THE DESCRIPTION ";: INVERSE : PRINT "A PERSON";: NORMAL : PRINT " DOES NOT": PRINT "NECESSARILY DENOTE A PROPER NAME."
  38. 96  VTAB 22: INPUT "THREE PLAYERS:";PL$(1),PL$(2),PL$(3)
  39. 97  IF  LEFT$(PL$(1),5) = "APPLE"  AND  LEFT$(PL$(2),5) = "APPLE"  AND  LEFT$(PL$(3),5) = "APPLE"  THEN  VTAB 22: CALL  -868: PRINT "DISPLAY ANSWERS (Y/";: INVERSE : PRINT "N";: NORMAL : PRINT ") ?";: GET YD$: PRINT 
  40. 98  VTAB 22: CALL  -868: PRINT "PRESS ANY KEY TO BEGIN...": GOSUB 11001
  41. 99  FOR LOOP = 1 TO 3:GT(LOOP) = 0:FS(LOOP) = 0: NEXT LOOP
  42. 100  FOR PZ = 1 TO 6: FOR LOOP = 1 TO 3:CASH(LOOP) = 0: NEXT LOOP
  43. 101 UL$ = "":G = G +1: IF G >3  THEN G = 3
  44. 102 ST = ST +1: IF ST >3  THEN ST = ST -3
  45. 103 CC = 1
  46. 120  IF G = 2  THEN  FOR LOOP = 1 TO 24:WH$(LOOP) = WI$(LOOP): NEXT LOOP
  47. 130  IF G = 3  THEN  FOR LOOP = 1 TO 24:WH$(LOOP) = WJ$(LOOP): NEXT LOOP
  48. 131 PW = 0
  49. 132  TEXT : HOME : PRINT "TOP MONEY IS $"MV(G)"  ";: HTAB 30: PRINT "PUZZLE #";PZ: POKE 34,1
  50. 133  FOR QQ = 1 TO 26:IP(QQ) = 0: NEXT QQ
  51. 134 ZT =  INT( RND(1) *QA +1):REAL$ = REAL$(ZT):ITZA$ = ITZA$(ZT): IF UP(ZT)  THEN 134
  52. 135  GOSUB 11002:UP(ZT) = 1
  53. 136  VTAB 16: FOR LOOP = 1 TO  LEN(REAL$): IF  MID$ (REAL$,LOOP,1) >"@"  AND  MID$ (REAL$,LOOP,1) <"["  THEN  PRINT  CHR$(95);: GOTO 138
  54. 137  PRINT  MID$ (REAL$,LOOP,1);
  55. 138  NEXT LOOP: NORMAL : PRINT 
  56. 139  VTAB 23: PRINT "THE PUZZLE IS : ";: INVERSE : PRINT ITZA$: NORMAL 
  57. 140 C = ST -1
  58. 141  IF  LEFT$(PL$(1),5) = "APPLE"  AND  LEFT$(PL$(2),5) = "APPLE"  AND  LEFT$(PL$(3),5) = "APPLE"  AND YD$ = "Y"  THEN  VTAB 22: PRINT RE$
  59. 145 C = C +1: IF C >3  THEN C = 1
  60. 146  POKE 34,1: VTAB 2: CALL  -868: PRINT PL$(C);"'";
  61. 147  IF  RIGHT$(PL$(C),1) < >"S"  THEN  PRINT "S";
  62. 148  PRINT " TURN": POKE 34,2
  63. 149 GHESS$ = " "
  64. 155  IF  LEFT$(PL$(C),5) = "APPLE"  THEN 1000
  65. 158  GOSUB 10000
  66. 159  GOSUB 9000
  67. 160 QT =  INT( RND(1) *30 +24)
  68. 170  FOR LOOP = 1 TO QT
  69. 171 PW = PW +1: IF PW = 25  THEN PW = 1
  70. 172  VTAB 4: PRINT WH$(PW);"        ":SPEAK =  PEEK( -16336):SPEAK =  PEEK( -16336)
  71. 173  FOR PAUSE = 1 TO 1.7 *LOOP: NEXT PAUSE: NEXT LOOP
  72. 174 FF =  FRE(0)
  73. 180  IF WH$(PW) = "FREE SPIN"  THEN FS(C) = FS(C) +1: GOTO 158
  74. 190  IF  VAL(WH$(PW))  THEN AMT =  VAL(WH$(PW))
  75. 191  IF WH$(PW) = "BANKRUPT"  THEN  CALL 771:CASH(C) = 0: GOSUB 11000: GOSUB 9000: GOTO 250
  76. 192  IF WH$(PW) = "LOSE A TURN"  THEN 250
  77. 193  VTAB 8: CALL  -868
  78. 200  VTAB 11: PRINT "INPUT GUESS....";: INPUT GUESS$:GUESS$ =  LEFT$(GUESS$,1):IZIT = 0: VTAB  PEEK(37): CALL  -868
  79. 201  IF (GUESS$ = "A"  OR GUESS$ = "E"  OR GUESS$ = "I"  OR GUESS$ = "O"  OR GUESS$ = "U")  AND GH$ < >"B"  THEN  PRINT "YOU CAN'T DO THAT, THAT'S A VOWEL."; CHR$(7): FOR PAUSE = 1 TO 400: NEXT PAUSE: VTAB  PEEK(37): CALL  -868: GOTO 200
  80. 202  IF GUESS$ <"A"  OR GUESS$ >"Z"  THEN  CALL  -198: HTAB 1: GOTO 200
  81. 203  GOSUB 7000
  82. 210  FOR LOOP = 1 TO  LEN(REAL$): IF  MID$ (REAL$,LOOP,1) = GUESS$  THEN IZIT = 1: VTAB 16: HTAB LOOP: PRINT GU$;: CALL  -198: IF GHESS$ < >"B"  THEN CASH(C) = CASH(C) +AMT
  83. 220  NEXT LOOP
  84. 230 ZY = 1: GOSUB 11000
  85. 240  VTAB 20: HTAB  ASC(GU$) -64: PRINT GU$;: HTAB 1
  86. 241 UL$ = UL$ +GU$
  87. 245  IF IZIT  THEN IP( ASC(GU$) -64) = 0: GOTO 260
  88. 249  FOR SS = 1 TO 15:SOUND =  PEEK( -16336) + PEEK( -16336) - PEEK( -16336): NEXT SS
  89. 250  IF FS(C)  THEN  VTAB 11: PRINT "WOULD YOU LIKE TO USE A FREE SPIN CARD  (Y/";: INVERSE : PRINT "N";: NORMAL : PRINT ") ?";: GET ZZ$: PRINT 
  90. 251  IF FS(C)  THEN  VTAB  PEEK(37): CALL  -868: VTAB  PEEK(37): CALL  -868: IF ZZ$ = "Y"  THEN FS(C) = FS(C) -1: GOTO 158
  91. 255  GOTO 145
  92. 260  IF   NOT  FN IP(1)  THEN  VTAB 10: GOSUB 10050: PRINT "ONLY VOWELS LEFT-YOU MUST GUESS!":GHESS$ = "G": GOTO 263
  93. 261  GOSUB 11004: INPUT GHESS$: VTAB  PEEK(37): CALL  -868: VTAB  PEEK(37): CALL  -868:GHESS$ =  LEFT$(GHESS$,1)
  94. 262  IF GHESS$ = "B"  AND CASH(C) > = 250  THEN CASH(C) = CASH(C) -250: GOSUB 9000: GOTO 200
  95. 263  IF GHESS$ = "G"  THEN  VTAB 11: INPUT "TYPE YOUR ANSWER. INCLUDE ALL SPACES.   ";GUESS$: IF GUESS$ = REAL$  THEN 8000
  96. 264  IF GHESS$ = "G"  AND GUESS$ < >REAL$  THEN  VTAB 10: CALL  -868: VTAB 11: CALL  -868: VTAB 12: CALL  -868: PRINT "SORRY, THAT'S WRONG!": FOR PAUSE = 1 TO 650: NEXT PAUSE: VTAB  PEEK(37): CALL  -868: ON ( SGN( FN IP(1)) +1) GOTO 266,145
  97. 265  IF GHESS$ = ""  OR GHESS$ = "S"  THEN 159
  98. 266  IF GH$ = "G"  AND GU$ < >RE$  AND   NOT  FN IP(1)  THEN  FOR PA = 10 TO 12: VTAB PA: CALL  -868: NEXT PA: VTAB 10: PRINT "WE'VE REACHED A DRAW. THE SOLUTION IS   BELOW. CASH ACCUMULATED ADDED TO VALUE  OF NEXT GAME.": VTAB 16: PRINT RE$: GOSUB 9503: GOTO 101
  99. 267  GOTO 260
  100. 999  REM  COMPUTER SECTION
  101. 1000  VTAB 11: PRINT "MY TURN.....": FOR PAUSE = 1 TO 150: NEXT PAUSE: VTAB  PEEK(37): CALL  -868
  102. 1001  GOSUB 9000
  103. 1002 QT =  INT( RND(1) *30 +24)
  104. 1003  FOR LOOP = 1 TO QT:PW = PW +1 +( -24 *(PW = 24)): VTAB 4: PRINT WH$(PW);"           ":SPEAK =  PEEK( -16336):SPEAK =  PEEK( -16336): FOR PAUSE = 1 TO 1.7 *LOOP: NEXT PAUSE,LOOP:FF =  FRE(0)
  105. 1004  IF WH$(PW) = "FREE SPIN"  THEN FS(C) = FS(C) +1: GOTO 1000
  106. 1005  IF  VAL(WH$(PW))  THEN AMT =  VAL(WH$(PW))
  107. 1006  IF WH$(PW) = "BANKRUPT"  THEN  CALL 771:CASH(C) = 0: GOSUB 9000: IF FS(C)  THEN FS(C) = FS(C) -1: VTAB 11: PRINT "I'LL USE A FREE SPIN CARD": FOR PAUSE = 1 TO 200: NEXT PAUSE: VTAB  PEEK(37): CALL  -868: GOTO 1001
  108. 1007  IF WH$(PW) = "BANKRUPT"  THEN 145
  109. 1008  IF WH$(PW) = "LOSE A TURN"  THEN  GOSUB 9000: IF FS(C)  THEN FS(C) = FS(C) -1: VTAB 11: PRINT "I'LL USE A FREE SPIN CARD": FOR PAUSE = 1 TO 200: NEXT PAUSE: VTAB  PEEK(37): CALL  -868: GOTO 1001
  110. 1009  IF WH$(PW) = "LOSE A TURN"  THEN 145
  111. 1010  VTAB 8: CALL  -868: VTAB 11
  112. 1011 GUESS$ =  MID$ (FL$,CC,1):CC = CC +1: FOR DD = 1 TO  LEN(UL$): IF GU$ =  MID$ (UL$,DD,1)  THEN 1011
  113. 1012  NEXT DD:IZIT = 0: VTAB 11: PRINT "I'LL GUESS...";GU$: FOR PAUSE = 1 TO 200: NEXT PAUSE: VTAB  PEEK(37): CALL  -868
  114. 1013  FOR LOOP = 1 TO  LEN(REAL$): IF  MID$ (REAL$,LOOP,1) = GUESS$  THEN IZIT = 1: VTAB 16: HTAB LOOP: PRINT GU$;: CALL  -198:CASH(C) = CASH(C) +AMT
  115. 1014  NEXT LOOP: VTAB 20: HTAB  ASC(GU$) -64: PRINT GU$;: HTAB 1
  116. 1015 UL$ = UL$ +GU$
  117. 1016  IF IZIT  THEN IP( ASC(GU$) -64) = 0: GOTO 1030
  118. 1017  FOR SS = 1 TO 15:SOUND =  PEEK( -16336) + PEEK( -16336) - PEEK( -16336): NEXT SS
  119. 1018  IF FS(C)  THEN FS(C) = FS(C) -1: VTAB 11: PRINT "I'LL USE A FREE SPIN CARD": FOR PAUSE = 1 TO 200: NEXT PAUSE: VTAB  PEEK(37): CALL  -868: GOTO 1001
  120. 1019  GOTO 145
  121. 1030  IF   NOT  FN IP(1)  THEN  VTAB 10: GOSUB 10050: PRINT "ONLY VOWELS LEFT...I'LL GUESS.": VTAB 12: SPEED= 100: PRINT RE$: SPEED= 255: GOTO 8000
  122. 1031  VTAB 11: PRINT "I'LL SPIN...": FOR PAUSE = 1 TO 200: NEXT PAUSE: VTAB  PEEK(37): CALL  -868: GOTO 1001
  123. 1999  END 
  124. 2000  REM  END OF DAY
  125. 2001  TEXT : HOME 
  126. 2020 GT = GT(1):GW = 1: IF GT(2) >GT  THEN GT = GT(2):GW = 2
  127. 2021  IF GT(3) >GT  THEN GT = GT(3):GW = 3
  128. 2030  PRINT "WITH A TOTAL OF $"GT;",": PRINT PL$(GW)" IS THE WINNER FOR TODAY!"
  129. 2035  FOR LOOP = 1 TO 10: CALL  -198: NEXT LOOP
  130. 2040  FOR PAUSE = 1 TO 1000: NEXT PAUSE
  131. 2044  PRINT 
  132. 2045  IF  LEFT$(PL$(GW),5) = "APPLE"  THEN  PRINT "IT LOOKS LIKE THE COMPUTER IS SMARTER   THAN THE REST OF YOU!": GOTO 6000
  133. 2050  PRINT "AND NOW, IF YOU'RE READY, WE'LL GO FOR  THE BONUS ROUND."
  134. 2060  PRINT "YOU'LL HAVE A PUZZLE ON WHICH YOU CAN   GUESS SIX LETTERS -- FIVE CONSONANTS ANDONE VOWEL.  IF YOU CAN GUESS THE PUZZLE,YOU'LL WIN $5,000 CASH."
  135. 2070  PRINT : PRINT "PRESS ANY KEY WHEN READY.": GOSUB 11001
  136. 2080  FOR QQ = 1 TO 26:IP(QQ) = 0: NEXT QQ:ZT =  INT( RND(1) *QA +1):REAL$ = REAL$(ZT): IF UP(ZT)  THEN 2080
  137. 2090  GOSUB 11002:UP(ZT) = 1
  138. 2110  VTAB 16: FOR LOOP = 1 TO  LEN(REAL$): IF  MID$ (REAL$,LOOP,1) >"@"  AND  MID$ (REAL$,LOOP,1) <"["  THEN  PRINT  CHR$(95);: GOTO 2112
  139. 2111  PRINT  MID$ (REAL$,LOOP,1);
  140. 2112  NEXT LOOP: NORMAL : PRINT 
  141. 2113  VTAB 23: PRINT "THE PUZZLE IS : ";: INVERSE : PRINT IT$(ZT): NORMAL 
  142. 2114  FOR L = 1 TO 15: VTAB L: CALL  -868: NEXT L: VTAB 8: PRINT "NOW, TYPE FIVE CONSONANTS, ALL AT ONCE  ";: INPUT CN$
  143. 2115  FOR L = 1 TO 5:KN$ =  MID$ (CN$,L,1): IF KN$ <"@"  OR KN$ >"["  OR (KN$ = "A"  OR KN$ = "E"  OR KN$ = "I"  OR KN$ = "O"  OR KN$ = "U")  THEN  PRINT  CHR$(7);: HTAB 1:L = 5: NEXT L: GOTO 2114
  144. 2116  NEXT L: VTAB 9: CALL  -868
  145. 2117  VTAB 8: PRINT "NOW, INPUT THE VOWEL                    ";: INPUT VO$
  146. 2118  IF (VO$ < >"A"  AND VO$ < >"E"  AND VO$ < >"I"  AND VO$ < >"O"  AND VO$ < >"U")  THEN  PRINT  CHR$(7);: GOTO 2117
  147. 2119  FOR L = 1 TO 5:GG$(L) =  MID$ (CN$,L,1): NEXT L:GG$(6) = VO$
  148. 2120  FOR L = 1 TO 6: FOR LOOP = 1 TO  LEN(REAL$): IF  MID$ (REAL$,LOOP,1) = GG$(L)  THEN  VTAB 16: HTAB LOOP: PRINT GG$(L);: CALL  -198
  149. 2121  NEXT LOOP,L
  150. 2122  VTAB 8: HTAB 1: CALL  -868: PRINT "FOR $5000, WHAT'S YOUR GUESS?": VTAB 9: CALL  -868: INPUT GU$: VTAB 9: CALL  -868
  151. 2123  IF GU$ < >RE$  THEN  VTAB 8: CALL  -868: PRINT "SORRY, THE ANSWER WAS...": VTAB 16: PRINT RE$: GOTO 2125
  152. 2124  VTAB 16: PRINT RE$: VTAB 8: CALL  -868: PRINT "RIGHT!!!!!<CTRL-G><CTRL-G><CTRL-G><CTRL-G><CTRL-G><CTRL-G><CTRL-G><CTRL-G><CTRL-G><CTRL-G>":GT = GT +5000
  153. 2125  VTAB 20: PRINT "TODAY, YOU WON...$";GT: PRINT "CONGRATULATIONS!!!!!": FOR LOOP = 1 TO 5: CALL  -198: NEXT LOOP: FOR PAUSE = 1 TO 500: NEXT PAUSE
  154. 6000  VTAB 21: CALL  -958: INVERSE : PRINT "PRESS C TO PLAY AGAIN, Q TO QUIT ";: GET YN$
  155. 6001  NORMAL : PRINT : IF YN$ = "C"  THEN FF =  FRE(0): CLEAR : RUN 
  156. 6002  IF YN$ < >"Q"  THEN 6000
  157. 6999  END 
  158. 7000  FOR LL = 1 TO  LEN(UL$): IF  MID$ (UL$,LL,1) = GUESS$  THEN  VTAB 11: PRINT "SORRY, YOU'VE USED A USED LETTER.": FOR PAUSE = 1 TO 1000: NEXT PAUSE: VTAB  PEEK(37): CALL  -868:LL =  LEN(UL$): NEXT LL: GOSUB 11000: POP : GOTO 255
  159. 7001  NEXT LL: RETURN 
  160. 8000  PRINT : PRINT PL$(C);" WINS!!!": FOR LOOP = 1 TO 5: CALL  -198: NEXT LOOP: GOSUB 9499: FOR PAUSE = 1 TO 1000: NEXT PAUSE: NEXT PZ: GOTO 2000
  161. 9000  NORMAL : VTAB 3: HTAB 31: PRINT 1: VTAB 4: HTAB 31: PRINT 2: VTAB 5: HTAB 31: PRINT 3: FLASH : VTAB 2 +C: HTAB 31: PRINT C: NORMAL 
  162. 9001  VTAB 2 +C: HTAB 33: PRINT  SPC( 0 +(CASH(C) <10000) +(CASH(C) <1000) +(CASH(C) <100) +(CASH(C) <10));CASH(C): RETURN 
  163. 9499  INVERSE : FOR CM = 1 TO 3: IF CM < >C  THEN CASH(CM) = 0
  164. 9500  NEXT CM: TEXT : VTAB 1: HTAB 29: INVERSE : PRINT "GRAND TOTAL": POKE 34,2
  165. 9501  FOR CM = 1 TO 3:GT(CM) = GT(CM) +CA(CM)
  166. 9502  VTAB 2 +CM: HTAB 31: PRINT CM: VTAB 2 +CM: HTAB 33: PRINT  SPC( 0 +(GT(CM) <10000) +(GT(CM) <1000) +(GT(CM) <100) +(GT(CM) <10));GT(CM): NEXT CM: NORMAL 
  167. 9503  FOR PAUSE = 1 TO 1000: NEXT PAUSE: RETURN 
  168. 10000  VTAB 11: INPUT "PRESS RETURN TO SPIN ";ZZ$: VTAB  PEEK(37): CALL  -868: RETURN 
  169. 10050  FOR QR = 1 TO 5: PRINT  CHR$(7);: FOR PAUSE = 1 TO 55: NEXT PAUSE,QR: RETURN 
  170. 11000  VTAB 8: HTAB 1: PRINT "YOUR CASH IS $"CASH(C)"    ": GOSUB 9000: RETURN 
  171. 11001  POKE  -16368,0: WAIT  -16384,128: POKE  -16368,0:FF =  INT( RND( PEEK(78) + PEEK(79) *256)): RETURN 
  172. 11002  FOR QR = 1 TO  LEN(REAL$):QR$ =  MID$ (REAL$,QR,1): IF QR$ < >" "  AND QR$ < >"-"  AND QR$ < >"'"  THEN IP( ASC(QR$) -64) = IP( ASC(QR$) -64) +1
  173. 11003  NEXT QR: RETURN 
  174. 11004  VTAB 11: PRINT "<RET> TO ";: INVERSE : PRINT "SPIN";: NORMAL : PRINT ", <G> TO GUESS THE PUZZLE";: IF CASH(C) > = 250  THEN  PRINT "  OR <B> TO BUY A VOWEL ";
  175. 11005  RETURN 
  176. 20000  REM <CTRL-H><CTRL-H><CTRL-H><CTRL-H><CTRL-H><CTRL-H><CTRL-H><CTRL-H><CTRL-H><CTRL-H><CTRL-H>----------------<CTRL-M><CTRL-M>WHEEL OF FORTUNE<CTRL-M><CTRL-M>JOE ISHAM<CTRL-M><CTRL-M>----------------